Excel VBA ChartObjectの基本｜グラフ作成の手順とコードを解説

chartObj.Chart.ChartType = xlColumnClustered '// 棒グラフを設定

chartObj.Chart.SetSourceData Source:=ws.Range("A1:C5") '// データ範囲を指定

Set chartObj = ws.ChartObjects.Add(Left:=100, Top:=50, Width:=400, Height:=300)

With chartObj
    .Left = 100   '// 左端の位置
    .Top = 50     '// 上端の位置
End With

With chartObj
    .Left = ws.Range("B2").Left  '// セルB2の左端に合わせる
    .Top = ws.Range("B2").Top    '// セルB2の上端に合わせる
End With

With chartObj
    .Width = 400  '// 横幅
    .Height = 300 '// 高さ
End With

With chartObj
    .Left = ws.Range("B2").Left      '// セルB2の左端に合わせる
    .Top = ws.Range("B2").Top        '// セルB2の上端に合わせる
    .Width = ws.Range("B2:D2").Width '// セルB2～D2の幅を適用
    .Height = ws.Range("B2:B4").Height '// セルB2～B4の高さを適用
End With

chartObj.Chart.HasTitle = True '// タイトルを表示

chartObj.Chart.ChartTitle.Text = "売上分析"

With chartObj.Chart.Axes(xlCategory) '// X軸（カテゴリ軸）
    .HasTitle = True
    .AxisTitle.Text = "月別" '// X軸のタイトル
End With

With chartObj.Chart.Axes(xlValue) '// Y軸（値軸）
    .HasTitle = True
    .AxisTitle.Text = "売上高" '// Y軸のタイトル
End With

With chartObj.Chart.Axes(xlValue, xlSecondary) ' 第二Y軸
    .HasTitle = True
    .AxisTitle.Text = "利益" ' 第二Y軸のタイトル
End With

Sub CustomizeAxes()
    Dim ws As Worksheet
    Dim chartObj As ChartObject

    '// シートとグラフを指定
    Set ws = ActiveSheet
    Set chartObj = ws.ChartObjects(1) '// シート上の最初のグラフを選択

    '// 第一X軸（カテゴリ軸）
    With chartObj.Chart.Axes(xlCategory)
        .HasTitle = True
        .AxisTitle.Text = "月別" '// X軸のタイトル
    End With

    '// 第一Y軸（値軸）
    With chartObj.Chart.Axes(xlValue)
        .HasTitle = True
        .AxisTitle.Text = "売上高" '// Y軸のタイトル
    End With

    '// 第二Y軸
    With chartObj.Chart.Axes(xlValue, xlSecondary)
        .HasTitle = True
        .AxisTitle.Text = "利益" '// 第二Y軸のタイトル
    End With
End Sub

With chartObj.Chart.Legend
    .Position = xlLegendPositionBottom '// 凡例を下に配置
End With

With chartObj.Chart.PlotArea.Interior
    .Color = RGB(240, 240, 240) '// 灰色
End With

chartObj.Delete '// グラフを削除

Dim chartObj As ChartObject

For Each chartObj In ActiveSheet.ChartObjects
    chartObj.Chart.ChartTitle.Text = "共通タイトル"
Next chartObj

Sub CreateCustomizedChartObject()
    Dim ws As Worksheet
    Dim chartObj As ChartObject
    
    '// アクティブシートを指定
    Set ws = ActiveSheet
    
    '// グラフを追加
    Set chartObj = ws.ChartObjects.Add(Left:=100, Top:=50, Width:=400, Height:=300)
    
    '// グラフの種類やデータ範囲、タイトルを設定
    With chartObj.Chart
        '// グラフの種類とデータ範囲
        .ChartType = xlColumnClustered '// 棒グラフに設定
        .SetSourceData Source:=ws.Range("A1:C5") '// データ範囲を指定
        
        '// グラフタイトルの設定
        .HasTitle = True
        .ChartTitle.Text = "月別売上と利益分析" '// グラフタイトルを設定
        
        '// 第一Y軸（値軸）のカスタマイズ
        With .Axes(xlValue)
            .HasTitle = True
            .AxisTitle.Text = "金額 (円)" '// Y軸のタイトル
        End With
        
        '// X軸（カテゴリ軸）のカスタマイズ
        With .Axes(xlCategory)
            .HasTitle = True
            .AxisTitle.Text = "月" '// X軸のタイトル
        End With
        
        '// 凡例をグラフの下に配置
        With .Legend
            .Position = xlLegendPositionBottom '// 凡例を下に配置
        End With
        
        '// グラフ背景色の設定
        With .PlotArea.Interior
            .Color = RGB(240, 240, 240) '// 背景色を灰色に設定
        End With
        
        '// データ系列のカスタマイズ（例: 第一系列の色を青に設定）
        With .SeriesCollection(1)
            .Format.Fill.ForeColor.RGB = RGB(0, 102, 204) '// 第一系列の色を青に
        End With
        
        '// 第二系列を第二Y軸に設定（例: 利益のデータ）
        If .SeriesCollection.Count > 1 Then
            With .SeriesCollection(2)
                .AxisGroup = xlSecondary '// 第二Y軸に割り当て
            End With
            
            '// 第二Y軸のカスタマイズ
            With .Axes(xlValue, xlSecondary)
                .HasTitle = True
                .AxisTitle.Text = "利益 (円)" '// 第二Y軸のタイトル
            End With
        End If
    End With
End Sub

Dim chartObj As ChartObject
Set chartObj = ActiveSheet.ChartObjects(1)

'// グラフタイトルを直接設定しようとするとエラー
chartObj.ChartTitle.Text = "売上分析" '// ←エラーになる

chartObj.Chart.ChartTitle.Text = "売上分析" '// Chartを介してアクセスする必要がある

Dim chartObj As ChartObject
If ActiveSheet.ChartObjects.Count > 0 Then
    Set chartObj = ActiveSheet.ChartObjects(1)
Else
    MsgBox "グラフが存在しません"
End If

Dim ws As Worksheet
Dim chartObj As ChartObject

Set ws = ActiveSheet
Set chartObj = ws.ChartObjects.Add(Left:=ws.Range("B2").Left, _
                                   Top:=ws.Range("B2").Top, _
                                   Width:=ws.Range("B2:D2").Width, _
                                   Height:=ws.Range("B2:B5").Height)

Application.ScreenUpdating = False
Dim chartObj As ChartObject

For Each chartObj In ActiveSheet.ChartObjects
    chartObj.Chart.ChartTitle.Text = "共通タイトル"
Next chartObj

Application.ScreenUpdating = True

On Error Resume Next
Dim chartObj As ChartObject

Set chartObj = ActiveSheet.ChartObjects(1)
chartObj.Chart.ChartType = xlLine '// 折れ線グラフに変更

If Err.Number <> 0 Then
    MsgBox "エラーが発生しました: " & Err.Description
    Err.Clear
End If
On Error GoTo 0

Dim dataRange As Range
Set dataRange = ActiveSheet.Range("A1:B10")

If Application.WorksheetFunction.CountA(dataRange) > 0 Then
    chartObj.Chart.SetSourceData Source:=dataRange
Else
    MsgBox "データ範囲が空です"
End If

Dim chartObj As ChartObject
Set chartObj = ActiveSheet.ChartObjects(1)

'// 棒グラフの場合のみ色を変更
If chartObj.Chart.ChartType = xlColumnClustered Then
    chartObj.Chart.SeriesCollection(1).Format.Fill.ForeColor.RGB = RGB(0, 128, 255)
Else
    MsgBox "この操作は棒グラフでのみ有効です"
End If

Sub CreateLineChart()
    Dim ws As Worksheet
    Dim chartObj As ChartObject
    Dim chartData As Range

    '// 売上データ範囲の設定
    Set ws = ThisWorkbook.Sheets(1)
    Set chartData = ws.Range("A1:B7") '// 月別売上データ範囲

    '// ChartObjectを追加
    Set chartObj = ws.ChartObjects.Add(Left:=50, Top:=50, Width:=400, Height:=300)

    '// グラフの種類とデータソースを設定
    With chartObj.Chart
        .ChartType = xlLine ' 折れ線グラフ
        .SetSourceData Source:=chartData

        '// グラフタイトルを設定
        .HasTitle = True
        .ChartTitle.Text = "月別売上推移"

        '// X軸（カテゴリ軸）ラベル設定
        With .Axes(xlCategory)
            .HasTitle = True
            .AxisTitle.Text = "月"
        End With

        '// Y軸（値軸）ラベル設定
        With .Axes(xlValue)
            .HasTitle = True
            .AxisTitle.Text = "売上 (円)"
        End With

        '// 凡例を非表示
        .HasLegend = False
    End With

    MsgBox "折れ線グラフを作成しました。", vbInformation
End Sub

Sub CreateLineChartWithCustomization()
    Dim ws As Worksheet
    Dim chartObj As ChartObject
    Dim chartData As Range

    '// データ範囲の設定（商品別売上データ）
    Set ws = ThisWorkbook.Sheets(1)
    Set chartData = ws.Range("A1:E4") '// 商品名と月別売上データ範囲

    '// ChartObjectを追加
    Set chartObj = ws.ChartObjects.Add(Left:=100, Top:=50, Width:=500, Height:=350)

    '// グラフの種類やデータを設定
    With chartObj.Chart
        .ChartType = xlLineMarkers '// 折れ線グラフ（マーカー付き）
        .SetSourceData Source:=chartData

        '// グラフタイトルを設定
        .HasTitle = True
        .ChartTitle.Text = "商品別 月別売上推移"

        '// 凡例を設定
        .HasLegend = True
        .Legend.Position = xlLegendPositionTop ' 凡例をグラフの上に配置

        '// X軸（カテゴリ軸）の設定
        With .Axes(xlCategory)
            .HasTitle = True
            .AxisTitle.Text = "月"
        End With

        '// Y軸（値軸）の設定
        With .Axes(xlValue)
            .HasTitle = True
            .AxisTitle.Text = "売上 (円)"
        End With

        '// グラフエリアの背景色を設定
        With .PlotArea.Format.Fill
            .ForeColor.RGB = RGB(230, 230, 250) '// 薄いラベンダー色
        End With
    End With

    MsgBox "商品別の折れ線グラフを作成しました！", vbInformation
End Sub

Sub CreateScatterPlotWithTrendlineAndCorrelation()
    Dim ws As Worksheet
    Dim chartObj As ChartObject
    Dim chartData As Range
    Dim xValues As Range
    Dim yValues As Range
    Dim correlationCoefficient As Double
    
    '// シートとデータ範囲を設定
    Set ws = ThisWorkbook.Sheets(1)
    Set chartData = ws.Range("A1:B11") '// 散布図データ範囲（A列: X軸, B列: Y軸）
    Set xValues = ws.Range("A2:A11")  '// X軸データ
    Set yValues = ws.Range("B2:B11")  '// Y軸データ
    
    '// ChartObjectを追加
    Set chartObj = ws.ChartObjects.Add(Left:=100, Top:=50, Width:=500, Height:=350)
    
    '// 散布図を作成
    With chartObj.Chart
        .ChartType = xlXYScatter '// 散布図
        .SetSourceData Source:=chartData
        
        '// グラフタイトルの初期設定
        .HasTitle = True
        .ChartTitle.Text = "散布図と近似曲線"
        
        '// X軸とY軸の設定
        With .Axes(xlCategory)
            .HasTitle = True
            .AxisTitle.Text = "X値"
        End With
        With .Axes(xlValue)
            .HasTitle = True
            .AxisTitle.Text = "Y値"
        End With
        
        '// 近似曲線を追加
        With .SeriesCollection(1).Trendlines.Add
            .Type = xlLinear '// 線形近似
            .DisplayEquation = True '// グラフに方程式を表示
            .DisplayRSquared = True '// グラフにR²値を表示
        End With
    End With
    
    '// 相関係数を計算
    correlationCoefficient = WorksheetFunction.Correl(xValues, yValues)
    
    '// グラフタイトルに相関係数を追加表示
    chartObj.Chart.ChartTitle.Text = "散布図と近似曲線" & vbCrLf & "相関係数: " & Format(correlationCoefficient, "0.000")
    
    MsgBox "散布図が作成されました。相関係数: " & Format(correlationCoefficient, "0.000"), vbInformation
End Sub