VBA FileDialogの使い方｜ファイル選択・フォルダ選択と初期フォルダ

VBAでファイル選択ダイアログやフォルダ選択ダイアログを表示したいときは、Application.FileDialog を使うと、ユーザーにファイルやフォルダを選んでもらえます。

この記事では、VBA FileDialog の基本から、ファイル選択、フォルダ選択、初期フォルダ指定、msoFileDialogFolderPicker、複数選択、拡張子フィルター、キャンセル処理まで、コピペしながら使える形でまとめます。

Sub PickOneFile()
    With Application.FileDialog(msoFileDialogFilePicker)
        .Title = "ファイルを選択してください"
        .InitialFileName = "C:\サンプル\"
        .AllowMultiSelect = False

        If .Show = True Then
            MsgBox "選択したファイル:" & vbCrLf & .SelectedItems(1)
        End If
    End With
End Sub

Sub PickOneFolder()
    With Application.FileDialog(msoFileDialogFolderPicker)
        .Title = "フォルダを選択してください"
        .InitialFileName = "C:\サンプル\"
        .AllowMultiSelect = False

        If .Show = True Then
            MsgBox "選択したフォルダ:" & vbCrLf & .SelectedItems(1)
        End If
    End With
End Sub

【　この記事の概要　】

VBA FileDialogでファイル選択ダイアログを開く基本コード

FileDialogは、ざっくり言うと「VBAからWindowsの選択画面を呼び出すための入口」です。　ファイルを選ぶ、フォルダを選ぶ、保存先を指定する、選択したファイルを開く、といった操作を、ユーザーの手で安全に選ばせられます。

VBA FileDialogの4種類｜ファイル選択・フォルダ選択ダイアログ・Open・SaveAs

引数の「fileDialogType」について解説

「fileDialogType」には4つの種類があり、それぞれ異なる目的で使用されます。

これらを理解し使い分けることで、状況に応じた適切な動作を簡単に実装できます。
※各タイプの具体的な動作については、次のセクションで詳しく解説します。

Application.FileDialogの引数・プロパティ・メソッド

VBAのFileDialogには、様々な「プロパティ」と「メソッド」があります。
ここでは、主要なものを紹介します。

プロパティについて |初期フォルダを指定する方法 (InitialFileName) など

メソッドについて

より詳しい情報は、Microsoft公式 – FileDialog プロパティを参照してみてください。

VBA FileDialogの動作｜fileDialogTypeで使い分ける4つのダイアログ

FileDialogの引数「fileDialogType」によって、ダイアログボックスの動作がどのように変わるかを説明します。

実際にコードをコピペして、試してみてください！

「msoFileDialogOpen」の場合の動作 ( ファイルを開く )

「ファイルを開く」ためのダイアログボックスについて解説します。

Sub msoFileDialogOpen_test()
    With Application.FileDialog(msoFileDialogOpen)
        .InitialFileName = "C:\サンプル"
        .AllowMultiSelect = False
        .Title = "msoFileDialogOpenの動作テスト"
        
        If .Show = True Then
            .Execute
            MsgBox "選択したファイルを開きました。" & vbLf & .SelectedItems(1)
        End If
    End With
End Sub

「msoFileDialogSaveAs」の場合の動作 ( ファイルを保存 )

「ファイルを保存」するためのダイアログボックスについて解説します。

Sub msoFileDialogSaveAs_test()
    Dim savePath As String
    
    With Application.FileDialog(msoFileDialogSaveAs)
        .InitialFileName = "C:\サンプル"
        .AllowMultiSelect = False
        .Title = "msoFileDialogSaveAsの動作テスト"
        
        If .Show = True Then
            savePath = .SelectedItems(1)
            '// 保存操作を実行
            ActiveWorkbook.SaveAs Filename:=savePath, FileFormat:=xlOpenXMLWorkbookMacroEnabled
        
            MsgBox "ファイルを保存しました。" & vbLf & savePath
        End If
    End With
End Sub

「msoFileDialogFilePicker」の場合の動作 ( ファイル選択 )

「ファイルを選択」するためのダイアログボックスについて解説します。

Sub msoFileDialogFilePicker_test()
    With Application.FileDialog(msoFileDialogFilePicker)
        .InitialFileName = "C:\サンプル"
        .AllowMultiSelect = False
        .Title = "msoFileDialogFilePickerの動作テスト"
        
        If .Show = True Then
            MsgBox "ファイルが選択されました。" & vbLf & .SelectedItems(1)
        End If
    End With
End Sub

「msoFileDialogFolderPicker」の場合の動作 ( フォルダ選択 )

「フォルダを選択」するためのダイアログボックスについて解説します。

Sub msoFileDialogFolderPicker_test()
    With Application.FileDialog(msoFileDialogFolderPicker)
        .InitialFileName = "C:"
        .AllowMultiSelect = False
        .Title = "msoFileDialogFolderPickerの動作テスト"
        
        If .Show = True Then
            MsgBox "フォルダが選択されました。" & vbLf & .SelectedItems(1)
        End If
    End With
End Sub

VBAの「FileDialog」の使用例 (複数選択・フィルター・キャンセル) をご紹介

それでは、FileDialogの使用例を紹介します。

以下に紹介する使用例は、すべてコピペしてすぐに実行できるコードです。
気になる例は、ぜひご覧いただき、実際に実行してみてください。

使用例1: 複数のファイル名を選択し、メッセージボックスで表示する

ダイアログボックスで複数のファイルを選択し、そのファイルをメッセージボックスで表示させる方法を紹介します。

主な使用用途 ：
選択した複数の画像ファイルをリサイズしたり、複数のExcelファイルを開いて内容を処理したりする場合に便利です。

Sub 複数のファイルを選択する()
    Dim selectedFiles As String
    Dim i As Long
    With Application.FileDialog(msoFileDialogFilePicker)
        .InitialFileName = "C:\サンプル"
        .AllowMultiSelect = True
        .Title = "使用例1: 複数のファイルをダイアログで選択する"
    
        If .Show = True Then
            selectedFiles = "ファイルが選択されました。" & vbLf
            
            For i = 1 To .SelectedItems.Count
                 selectedFiles = selectedFiles & .SelectedItems(i) & vbLf
            Next i
        
            MsgBox selectedFiles
        End If
    End With
End Sub

処理結果

コードの動作概要

このコードで使用している機能

• Dim (変数)
• With (オブジェクトを繰り返し使用)
• IF (条件分岐)
• For (繰り返し)
• MsgBox (メッセージボックス)

1行ずつコードを解説

このコードを使用すると、複数のファイルを一括処理する必要がある場合に非常に便利です。
各ファイルに対する後続の処理をこの基盤の上で追加することで、様々な用途に応用可能です。

使用例2: フィルターを使用し、特定のファイルだけ選択する

エクセルファイルだけを選択できるように「フィルター」を設定して、ファイルを選択する方法を紹介します。

主な使用用途 ：
Excelファイルだけを選択できるようにし、誤ったファイル形式が選ばれることを防ぎます。
これは、データ入力やファイル操作の正確性を高める際に特に有効です。

Sub ファイルフィルターを追加して選択する()
    With Application.FileDialog(msoFileDialogFilePicker)
        .InitialFileName = "C:\サンプル"
        .AllowMultiSelect = False
        .Title = "使用例2: ファイルフィルターを追加して選択する"
        .Filters.Clear
        .Filters.Add "Excel Files", "*.xlsx; *.xlsm", 1
        .Filters.Add "All Files", "*.*", 2
        
        If .Show = True Then
            MsgBox "ファイルが選択されました。" & vbLf & .SelectedItems(1)
        End If
    End With
End Sub

処理結果

コードの動作概要

このコードで使用している機能

• With (オブジェクトを繰り返し使用)
• IF (条件分岐)
• MsgBox (メッセージボックス)

1行ずつコードを解説

このコードは、特定の種類のファイルのみを選択させたい場合に非常に有用です。
フィルターを適用することで、ユーザーが誤ったファイルを選択することを防ぎ、操作の正確性を確保します。
また、選択されたファイルのパスを簡単に取得し、後続の処理に活用できるため、VBAを使ったファイル操作を効率化することができます。

使用例3: ファイル選択をキャンセルしてもエラーが発生しない処理

ユーザーが「キャンセル」をクリックした場合でもエラーが発生せず、処理を安全に終了する方法を紹介します。
この方法では、ファイルダイアログを関数内で処理し、キャンセル時には空の文字列を返すことでエラーを防ぎます。

主な使用用途
このコードは、VBAでファイルを選択するダイアログを使用する際、ユーザーがファイルを選択しなかった場合（キャンセルした場合）でもエラーが発生しないようにしたい場合に使用します。ファイルが選択された場合のみ、後続の処理を実行できます。

Sub MainProcess()
    Dim filePath As String
    
    '// ファイルダイアログを使用してファイルを選択
    filePath = SelectFileDialog()
    
    '// キャンセルされた場合、処理を終了
    If filePath = "" Then
        MsgBox "キャンセルされました。処理を終了します。"
        Exit Sub
    End If
    
    '// ファイルが選択された場合の処理
    MsgBox "選択されたファイル: " & filePath
    '// ここにファイルを開く処理などを追加
End Sub


Function SelectFileDialog() As String
    With Application.FileDialog(msoFileDialogFilePicker)
        .Title = "ファイルを選択してください"
        .InitialFileName = "C:\サンプル"
        .AllowMultiSelect = False
        
        '// ユーザーがファイルを選択したかどうかを確認
        If .Show = True Then
            '// 選択されたファイルパスを返す
            SelectFileDialog = .SelectedItems(1)
        Else
            '// キャンセルされた場合は空の文字列を返す
            SelectFileDialog = ""
        End If
    End With
End Function

処理結果

コードの動作概要

このコードで使用している機能

• Dim (変数宣言)
• With (オブジェクトを繰り返し使用)
• If (条件分岐)
• Function (関数定義)
• MsgBox (メッセージボックス)

1行ずつコードを解説

このコードは、ユーザーがファイルダイアログで「キャンセル」を選択した場合でも、エラーを出さずにスムーズに処理を終了させる方法を提供します。
特に、ファイルを開く前にユーザーの選択を確認し、キャンセル時に適切なメッセージを表示することで、ユーザーフレンドリーなインターフェースを実現します。

この構成を使用することで、ファイル選択ダイアログをより安全かつ効果的に扱うことができ、エラー処理やユーザー体験の向上が期待できます。

使用例4: フォルダを選択し、保管されているファイルをセルに転記する方法

ダイアログボックスでフォルダを選択し、Dir関数を使用しそのフォルダ内にあるファイルのリストをExcelのセルに転記する方法を紹介します。

主な使用用途
選択したフォルダ内のファイルをリストとして表示したり、特定の処理を実行する際に便利です。
例えば、指定フォルダ内のすべてのファイルを一括で処理する場合に有効です。

Sub FolderToCell()
    Dim folderPath As String
    Dim fileName As String
    Dim i As Integer
    
    '// フォルダ選択ダイアログを表示
    With Application.FileDialog(msoFileDialogFolderPicker)
        .InitialFileName = "C:\サンプル"
        .Title = "フォルダを選択してください"
        If .Show = True Then
            folderPath = .SelectedItems(1) & "\"
        Else
            MsgBox "フォルダが選択されませんでした。"
            Exit Sub
        End If
    End With
    
    '// 選択したフォルダ内のファイルを取得してセルに転記
    i = 1
    fileName = Dir(folderPath & "*.*") '// フォルダ内の最初のファイルを取得
    Do While fileName <> ""
        Cells(i, 1).Value = fileName '// A列にファイル名を転記
        i = i + 1
        fileName = Dir '// 次のファイルを取得
    Loop
End Sub

処理結果

コードの動作概要

このコードで使用している機能

• Dim (変数宣言)
• With (オブジェクトを繰り返し使用)
• If (条件分岐)
• Dir関数 (ファイル名・パス取得)
• Do While (ループ処理)
• MsgBox (メッセージボックス)

1行ずつコードを解説

このコードは、ユーザーが選択したフォルダ内の全てのファイルをExcelのセルにリスト表示するのに便利です。
特定のフォルダ内のファイルを一括で処理する場合などに応用できます。
これにより、ファイル選択や管理が簡単に行えるようになります。

VBAを体系的に学びたい方へ

FileDialog、Dir、For、If、Functionが混ざると、コピペだけでは不安になることがあります。 基礎から確認したい方には、動画講座や入門記事を補助として使うのが向いています。

VBAの学習ロードマップを見る

スマホで後から読む

VBA FileDialogのFAQ｜GetOpenFilenameとの違いと参照設定

最後に、FileDialogと良く混同するGetOpenFilename との違い、参照設定、初期フォルダが開かない場合の確認ポイントをまとめます。　

VBA FileDialogとGetOpenFilenameの違い

msoFileDialogFolderPickerの参照設定とFAQ

Excel VBAで Application.FileDialog(msoFileDialogFolderPicker) を使う場合、通常はExcelのVBA環境からそのまま使えます。　もし msoFileDialogFolderPicker が認識されない場合は、定数名の入力ミス、Office環境、参照設定、実行場所を確認します。

FileDialogの使用に参照設定は必要ですか？

Excel VBAで Application.FileDialog を使う場合、通常はそのまま使えます。　Word、Outlook、Accessなど別のOfficeアプリから使う場合や、msoFileDialogFolderPicker などの定数が認識されない場合は、Microsoft Office Object Libraryの参照設定や、定数名のスペルを確認してください。

SelectedItems(2)以降も使えますか？

使えます。
.AllowMultiSelect = True にして複数ファイルを選んだ場合、.SelectedItems(1)、.SelectedItems(2) のように1始まりで取得できます。　件数は .SelectedItems.Count で確認します。

OutlookやWord VBAでFileDialogが動かない理由は？

Excelの Application.FileDialog と同じ感覚で書くと、実行しているOfficeアプリの違いや参照設定の違いでエラーになることがあります。　Excel以外で使う場合は、実行元アプリのオブジェクトモデル、Office Object Libraryの参照、定数が認識されているかを確認します。

Filters.Addを何度も呼ぶとフィルターが増えるときは？

.Filters.Add の前に .Filters.Clear を入れます。　これを忘れると、同じダイアログ設定を繰り返し使うときにフィルターが累積して、選択肢が増えて見づらくなります。

InitialFileNameに存在しないパスを渡したらどうなりますか？

指定した場所で開かず、前回の場所や既定の場所が表示されることがあります。　実務コードでは Dir 関数などでフォルダの存在を確認し、存在しない場合は ThisWorkbook.Path やドキュメントフォルダへ切り替えると安定します。

フォルダ選択でファイルも一緒に選べますか？

同じダイアログでファイルとフォルダを同時に選ぶ用途には向きません。　ファイルを選ぶなら msoFileDialogFilePicker、フォルダを選ぶなら msoFileDialogFolderPicker を使い分け、必要ならダイアログを2回表示します。

よくあるミスと対策を見る

スクロールできます

症状	原因の例	対策
キャンセル時にエラーになる	.Show の判定前に SelectedItems(1) を 読んでいる	If .Show = True Then の中だけで取得する
初期フォルダが思った場所にならない	パスが存在しない、末尾の \ がない、 古い履歴が使われる	存在するフォルダパスを指定し、必要なら Dir で事前確認する
フォルダが選べない	msoFileDialogFilePicker を使っている	msoFileDialogFolderPicker に変更する
複数選択の処理で型が合わない	複数の結果を1つの文字列として扱っている	For で SelectedItems を1件ずつ処理する
保存時に拡張子エラーが出る	拡張子と FileFormat が合っていない	.xlsm なら xlOpenXMLWorkbookMacroEnabled を使う

VBA FileDialogのまとめと次に読む記事

さらに学ぶために

FileDialogの使い方に慣れてきたら、他のVBA機能も活用してみましょう。

ユーザーフォームやイベント処理など、VBAにはさまざまな機能も同等の処理を行うことができます。
これらを学ぶことで、さらに高度な自動化が可能になり、作業の効率化を図ることができます。

まずは、この記事の内容を実践し、FileDialogを使いこなせるようになってください。
次に進むための基礎がしっかりと身につくはずです。

この記事が役に立ったと思った方は、ぜひサイトマップから違う記事もご覧ください。

+

S

Schedika

ローカルガントチャート

買い切り 2,980円

Excel工程表の作り直しを、ローカルで軽くする。

クラウド登録なし。ドラッグでガントを編集し、必要なときだけCSVやExcel補助ブックへ戻せます。

• 外部送信なし
• Excelへ提出可
• インストール不要

Schedikaの販売ページを見る

画像出典: zangyo-free.com / Schedika販売ページ

あわせて読みたい

サイトマップ このページは、本サイトの記事を分かりやすくまとめました。ぜひご覧ください。 目次 「共通」を見る 「VBA」を見る 「Officeスクリプト」を見る 「ワークシート関数」...