VBAで2次元配列をマスターする：データの効率的な管理と操作方法

「VBAで複雑なデータを扱う際、2次元配列はどうやって使うんだろう…」
そんな疑問を持っていませんか？

・データをExcelシートのように整理して管理したい

・2次元配列の基本的な概念を理解したい

・VBA初心者でも簡単に2次元配列を使いこなしたい

その場合は、VBAの「2次元配列」を
使用すると解決します！

この記事では、「VBAの2次元配列」を使ってデータを効率的に管理する方法を詳しく解説します。
静的・動的な宣言方法やExcelシートへの貼り付け方法も含めて、分かりやすく解説しています。

2次元配列を使うことで、複雑なデータ構造をシンプルに扱い、プログラムの効率性を大幅に向上させることができます。　さらに、Excelシートのようなデータ操作がコード内で完結し、手作業を自動化して作業時間を大幅に短縮することができます。

使用例もすべてコピペして実行できるので、ぜひ最後までご覧いただき、実践してみてください。

そもそも配列とは？という方は、そちらを解説した記事もありますので是非ご覧ください。

あわせて読みたい

VBA 配列の使い方徹底解説：宣言、初期化、動的配列・ソートもわかる基本ガイド 「ループ処理を使ってセルにデータを転記していたけれど、データが増えると動作が遅くなる…」このように困ったことはありませんか？ ・複数のデータをまとめて管理する...

【　この記事の概要　】

VBAをしっかり学びたいけれど、「どこから始めればいいかわからない」と迷っていませんか？

そんな方には、UdemyのVBA講座がおすすめです。

動画での丁寧な解説や、実践的な学習スタイルで、初心者でも無理なく基礎から応用まで習得できます。
自己学習を進める上で、何度でも繰り返し見返せる講座は非常に心強い味方になりますよ！

＼ 　自分のペースで学べるVBA講座はこちら　 ／

【 Udemy 】初心者でも安心！VBA講座を見る

​

この記事で「できるようになる」こと

この記事を読むことで、以下のことができるようになります。

VBAの2次元配列で何ができる？ どんな場面で使われるの？

VBAの「2次元配列」は、データを行と列で整理して管理できる便利な仕組みです。
特に、大量のデータを効率的に処理したり、Excelシートのようにデータを視覚的に操作したりしたい場合に活躍します。

なぜ2次元配列が役立つのか？

2次元配列を使用することで、以下のようなメリットがあります。

2次元配列が良く使用される場面

VBAを使ったデータ処理において、以下のような場面で特に活用されています。

VBAの「2次元配列」の基本 | 行と列でデータを効率管理

2次元配列とは、行と列の両方にインデックスを持つ配列のことです。
Excelのシートのように、行と列でデータを整理するのに適しており、複数のデータセットを効率的に管理できます。

2次元配列をエクセルのセルを使用して解説

VBAの2次元配列では、データが行と列で構成されており、それぞれにインデックス番号が割り振られています。
以下のようなExcelシートと同じようにイメージするとわかりやすいでしょう。

この場合、myArray(1, 1) は「1」に対応し、myArray(2, 2) は「4」に対応します。
インデックスを使うことで、特定のデータにアクセスすることができます。
※この説明では、エクセルの表と合わせるため、要素の下限を「1」としていますが、通常「0」から始まります。

VBA 2次元配列の宣言方法｜静的・動的の違いをわかりやすく解説

VBAで「2次元配列」を使用する際、まずDimステートメントを使用して配列を宣言する必要があります。
配列の宣言方法には、以下の2種類があります。

「静的配列」を使用し「2次元配列」を宣言する場合

具体的なコードの宣言例

'// 3行4列の静的配列を宣言
Dim myArray(2, 3) As Long

「動的配列」を使用し「2次元配列」を宣言する場合

具体的なコードの宣言例

'// 動的配列を宣言（初期サイズは未指定）
Dim myArray() As Long

'// 配列サイズを設定（3行4列）
ReDim myArray(2, 3)

静的配列と動的配列の違いを比較

VBAで2次元配列にデータを格納する方法｜CurrentRegionの使い方も解説

VBAの2次元配列は、行と列のインデックスを使用してデータを効率的に管理できます。
このセクションでは、以下の2つの方法を解説します。

CurrentRegionを使用して範囲を配列に格納 | 使用頻度 :

CurrentRegionを使用すると、指定したセルを起点に連続した範囲を自動で選択し、配列として格納できます。
これを使うと、指定した範囲のデータを一括で配列に格納できます。

コード例

Sub GetArrayFromRange()
    Dim arr As Variant
    
    '// 範囲全体を配列に格納
    arr = Range("A1").CurrentRegion.Value
    
    MsgBox "配列の下限要素: " & LBound(arr, 1) & ", " & LBound(arr, 2)
End Sub

処理結果

このコードでは、セル「A1」を起点とした範囲全体をCurrentRegionを使って取得し、配列「arr」に格納しています。

• CurrentRegionを使って取得した配列は、通常のVBA配列と異なり、下限要素が「1」から始まります。
  これは、Excelのシートの行・列のインデックスが「1」から始まることと一致しています。
• CurrentRegionは、空白行や空白列で区切られた範囲までしか取得できません。
  空白がある場合、意図した範囲全体が取得されない可能性があるため注意してください。

あわせて読みたい

VBA CurrentRegionでセル範囲を自動取得・最終行やセル操作を解説 「表のセル範囲をExcel VBA CurrentRegionを使って自動で取得するにはどうしたらいいんだろう．．．」そんなお悩みを抱えていませんか？ ・表のデータ範囲を自動で取得...

手動でデータを格納する方法 | 使用頻度 :

手動でデータを格納する方法は、配列の内容があらかじめ決まっている場合や、小規模なデータ処理に適しています。

コード例

Sub StoreDataIn2DArray()
    '// 3行4列の配列を宣言
    Dim myArray(2, 3) As Long
    
    '// データの格納
    myArray(0, 0) = 1
    myArray(0, 1) = 2
    myArray(0, 2) = 3
    myArray(0, 3) = 4
    myArray(1, 0) = 5
    myArray(1, 1) = 6
    myArray(1, 2) = 7
    myArray(1, 3) = 8
    myArray(2, 0) = 9
    myArray(2, 1) = 10
    myArray(2, 2) = 11
    myArray(2, 3) = 12
End Sub

処理結果

上記のコードでは、myArrayという2次元配列を作成し、各行と列にデータを格納しています。
例えば、myArray(0, 0) = 1は、1行1列目に「1」を格納することを示します。

このコードは、配列内容をコード内で明確に定義できるため、テスト用データや小規模データを準備する際に便利です。

指定範囲（Range）を使用する方法 | 使用頻度 :

特定の範囲を配列に取り込むには、Range.Valueを使用します。
この方法は、任意の範囲を柔軟に操作できるのが特徴です。

コード例

Sub GetArrayFromRangeDirect()
    Dim arr As Variant

    '// A1:D3範囲を配列に格納
    arr = Range("A1:D3").Value
End Sub

処理結果

このコードでは、指定したセル範囲「A1」から「D3」までのデータを取得し、配列「arr」に格納しています。

Rangeを使用して範囲を明示的に指定するため、CurrentRegionでは取得できない不連続なデータにも対応可能となります。

VBAの2次元配列を使用する際の注意ポイント

2次元配列を使用する際には、以下のポイントに注意する必要があります。

注意ポイント1: CurrentRegionで配列を取得する際のインデックスの違い

CurrentRegionを使用してExcelのデータ範囲を配列に格納すると、配列のインデックスが通常の配列とは異なります。
最下位の要素が「0」ではなく「1」から始まります。

この特性を理解しておかないと、配列操作で思わぬエラーが発生する可能性があります。

コード例: CurrentRegionで配列を取得する場合

Sub CurrentRegionExample()
    Dim arr As Variant
    Dim i As Long, j As Long

    '// CurrentRegionを使用して範囲を配列に格納
    arr = Range("A1").CurrentRegion.Value

    '// 配列のインデックスが1から始まる点に注意
    For i = LBound(arr, 1) To UBound(arr, 1)
        For j = LBound(arr, 2) To UBound(arr, 2)
            Debug.Print "行 " & i & " 列 " & j & ": " & arr(i, j)
        Next j
    Next i
End Sub

処理結果

ポイント

注意ポイント2: 配列データをセルに貼り付ける際のサイズ一致の重要性

2次元配列をExcelシートに貼り付ける際は、配列のサイズとセル範囲が一致している必要があります。
範囲が一致していない場合、エラーや意図しない動作が発生します。

コード例: 配列データをセルに貼り付ける

Sub PasteArrayToSheet()
    Dim myArray(0 To 2, 0 To 3) As Long
    Dim i As Long, j As Long

    '// 配列にデータを格納
    For i = 0 To 2
        For j = 0 To 3
            myArray(i, j) = (i + 1) * (j + 1)
        Next j
    Next i

    '// 配列をシートに貼り付け（範囲サイズを正確に指定）
    Sheets("Sheet1").Range("A1").Resize(UBound(myArray, 1) + 1, UBound(myArray, 2) + 1).Value = myArray
End Sub

ポイント

注意ポイント3: Transpose関数の制限と手動転置の活用法

Transpose関数を使用すると、2次元配列の行と列を入れ替えることができます。
ただし、配列が大きい場合やデータ型が適さない場合、エラーが発生することがあります。

コード例: Transposeを使用して転置する

Sub TransposeArrayExample()
    Dim myArray(0 To 2, 0 To 3) As Long
    Dim transposedArray As Variant
    Dim i As Long, j As Long

    '// 配列にデータを格納
    For i = 0 To 2
        For j = 0 To 3
            myArray(i, j) = (i + 1) * (j + 1)
        Next j
    Next i

    '// 配列を転置（Transpose関数を使用）
    transposedArray = Application.Transpose(myArray)

    '// 転置後の配列をシートに貼り付け
    Sheets("Sheet1").Range("A1").Resize(UBound(transposedArray, 1), UBound(transposedArray, 2)).Value = transposedArray
End Sub

ポイント

注意ポイント4: 2次元配列は最終次元しか変更できない

VBAでは、2次元配列のサイズを変更する場合、ReDim Preserveを使用すると最終次元（通常は列数）しか変更できません。
これはVBAの仕様による制限で、行数を変更するには配列全体を再宣言する必要があります。

コード例: 最終次元（列数）を変更する　⇒　エラーは出ません

Sub ResizeLastDimension()
    Dim myArray() As Long

    '// 動的配列を宣言
    ReDim myArray(2,3) '// 初期サイズ: 3行4列

    '// 列数を変更（可能）
    ReDim Preserve myArray(2,5) '// サイズ変更後: 3行6列
End Sub

コード例: 行数 (最終次元以外) を変更しようとするとエラーになる

Sub ResizeFirstDimensionError()
    Dim myArray() As Long

    '// 動的配列を宣言
    ReDim myArray(2,3) '// 初期サイズ: 3行4列

    '// 行数を変更しようとする（エラーが発生）
    ReDim Preserve myArray(4,3) '// エラー: Preserveでは最終次元しか変更できません
End Sub

ポイント

VBA「2次元配列」の使用例をご紹介

ここでは、2次元配列を活用した具体的な使用例を紹介します。

以下に紹介する使用例は、すべてコピペしてすぐに実行できるコードです。
気になる例は、ぜひご覧いただき、実際に実行してみてください。

VBAの基礎から応用までを効率よくしっかり学習したい方には、UdemyのVBA講座もおすすめです。

特に自己学習で進める場合、ビデオや実践例があると理解が進みやすくなります。

＼ 　自分のペースで学べるVBA講座はこちら　 ／

【 Udemy 】初心者でも安心！VBA講座を見る

​

使用例1: 2次元配列にデータを格納してシートに貼り付ける

2次元配列にデータを格納し、そのデータをExcelシートに貼り付ける方法を紹介します。

主な使用用途
この方法は、大量のデータを管理し、迅速にシート上に反映させる必要がある場合に特に有効です。
個別にデータを入力する手間を省き、ミスを防ぐためにも、2次元配列を活用することで、業務の効率化を図ることが可能です。

コード例

Sub PasteArrayToRange()
    Dim myArray(2, 3) As Long
    
    '// 配列にデータを格納
    myArray(0, 0) = 1
    myArray(0, 1) = 2
    myArray(0, 2) = 3
    myArray(0, 3) = 4
    myArray(1, 0) = 5
    myArray(1, 1) = 6
    myArray(1, 2) = 7
    myArray(1, 3) = 8
    myArray(2, 0) = 9
    myArray(2, 1) = 10
    myArray(2, 2) = 11
    myArray(2, 3) = 12
    
    '// 配列のデータをシートに貼り付け
    Sheets("Sheet1").Range("A1:D3").Value = myArray
End Sub

処理結果

コードの動作概要

このコードで使用している機能

1行ずつコードを解説

この使用例では、2次元配列を使って複数のデータを効率的に管理し、そのデータを一括でExcelシートに反映する方法を学ぶことができます。
これにより、手動でデータを入力する手間を省き、より迅速なデータ処理が可能になります。

使用例2: CurrentRegion使ってシートにデータを貼り付ける

CurrentRegionを使ってシート上のデータを2次元配列に格納し、そのデータを別のシートに貼り付ける方法を紹介します。

主な使用用途
このコードは、シート上のデータを2次元配列に格納し、そのデータを別のシートに一括で貼り付ける場合に使用します。
これにより、データの効率的な転送が可能となり、手動でのデータコピーよりも迅速かつ正確に処理が行えます。

コード例

Sub ArrayAndPaste()
    Dim arr As Variant
    
    '// 範囲全体を配列に格納
    arr = Range("A1").CurrentRegion.Value
    
    '// データをシートに貼り付け
    With Sheets("Sheet2")
        .Range(.Cells(1, 1), .Cells(UBound(arr, 1), UBound(arr, 2))) = arr
    End With
End Sub

処理結果

コードの動作概要

このコードで使用している機能

1行ずつコードを解説

このサブルーチンは、ExcelのSheet1にあるデータをすべてコピーし、Sheet2に一括で貼り付けることができます。
手動でのコピー＆ペースト操作よりも正確で効率的です。
特に、データ量が多い場合や定期的に行う操作を自動化したい場合に非常に便利です。

使用例3: CurrentRegionで取得したデータに条件分岐を適用し、別のシートに貼り付ける

この例では、CurrentRegionを使ってシート上のデータを2次元配列に格納し、その配列のデータに条件分岐を適用してから、条件に合致するデータのみを別のシートに貼り付ける方法を紹介します。

主な使用用途
CurrentRegionで取得したデータを条件分岐に基づいてフィルタリングし、条件に合致するデータだけを別のシートに転記する操作を行います。
これにより、大量のデータから特定の条件に一致する情報を効率的に抽出し、別の場所に出力することが可能になります。

コード例

Sub FilterAndPasteData()
    Dim arr As Variant
    Dim filteredArray() As Variant
    Dim i As Long, j As Long
    Dim rowCount As Long
    
    '// 範囲全体を配列に格納
    arr = Sheets("Sheet1").Range("A1").CurrentRegion.Value
    
    '// フィルタリングしたデータを格納する配列のサイズを初期化
    ReDim filteredArray(UBound(arr, 1) - 1, UBound(arr, 2) - 1)
    rowCount = 0
    
    '// 条件に合うデータのみを別の配列に格納
    For i = 1 To UBound(arr, 1)
        If arr(i, 5) >= 1200 Then '// 例えば、5列目の値が1200以上の場合にデータを抽出
            For j = 1 To UBound(arr, 2)
                filteredArray(rowCount, j - 1) = arr(i, j)
            Next j
            rowCount = rowCount + 1
        End If
    Next i
    
    '// フィルタリングしたデータをSheet2に貼り付け
    Sheets("Sheet2").Range("A1").Resize(rowCount, UBound(filteredArray, 2) + 1).Value = filteredArray
End Sub

処理結果

コードの動作概要

このコードで使用している機能

1行ずつコードを解説

このコードでは、CurrentRegionを使用してシート上のデータを2次元配列に格納し、その中から特定の条件（ここでは5列目の値が1200以上）に合致するデータをフィルタリングして、別のシートに貼り付けます。
特定の条件に基づいてデータを効率的に抽出し、別シートに移動することができるため、データの整理や分析に役立ちます。

この記事のまとめ

2次元配列は、VBAプログラミングにおいて複雑なデータ構造を整理し、効率的に管理するための強力なツールです。
データをExcelシートのように扱う場面では特に有用で、柔軟で効率的なプログラム作成に貢献します。

この記事では、2次元配列の基本的な概念からデータの格納方法、さらにExcelシートへのデータの貼り付け方法まで詳しく解説しました。
これらの知識を活用することで、データ管理がよりシンプルになり、プログラムの可読性も向上します。

ポイントのおさらい

さらに学ぶために

動的配列の基本を理解したら、次は配列を使った高度なデータ操作や、他の配列関連の技術に挑戦してみましょう。
データ管理のスキルが向上し、より複雑なシナリオにも対応できるようになります。

あわせて読みたい

サイトマップ このページは、本サイトの記事を分かりやすくまとめました。ぜひご覧ください。 目次 「VBA」を見る 「Officeスクリプト」を見る 「ワークシート関数」を見る 「JavaScr...